Introduction
This tutorial introduces the use of point clouds and brick maps for occlusion shading. The shader, listing 1, applies unusual color tinting to the occlusion that it assigns to a surface - figure 1.
Figure 1
Listing 1
surface
tinted_occlusion (float samples = 32,
sampleangle = 90.0,
maxdist = 1000000;
string bakename = "",
channels = "";
color camera_color = 1;
output varying float _occlusion = 0;
output varying color _Cs = 0;
)
{
normal n = normalize(N),
nf = faceforward(n, I);
float d;
Oi = Os;
// We have the brickmap with the pre-calculated
// occlusion values...
if(match("bkm$", bakename)) {
texture3d(bakename, P, n,
"_occlusion", _occlusion, "_Cs", _Cs);
}
else // we have to calculate the occlusion
{
if(rayinfo("depth", d))
{
if(d == 0) // ...I've been hit by a camera ray
{
color hitc = 0;
gather("illuminance", P, n,
radians(sampleangle), samples,
"surface:Cs", hitc)
{
_occlusion += 1;
_Cs += hitc;
}
else // gather failed to hit a surface
_Cs += 1;
// Calculate the averages...
_occlusion = 1 - _occlusion/samples;
_Cs =_Cs/samples;
if(bakename != "")
bake3d(bakename, channels, P, n,
"_occlusion", _occlusion,
"_Cs", _Cs);
}
}
}
// Note: Cs is not used
Ci = Os * camera_color * _occlusion * _Cs;
}
|
In addition to calculating an occlusion value - or
reading a previously saved value from a brickmap - the tinted_occlusion
shader averages the colors
of the surfaces that occlude the surface being shaded. Thus a red sphere on a white
polygon causes reddish occlusion to appear on the polygon.
The color assigned to an object, say,
Color 1 0 0
Sphere 1 -1 1 360
does not effect the color of the object as seen by the camera but, instead, causes
another surface that is occluded by the object to be tinted. The shader provides
a parameter called "camera_color" and it is the color assigned to this parameter
that controls the visual coloration as "seen" by the camera.
The shader either reads a brickmap, if the parameter "bakename" has the file
extension "bkm", or it writes data to a point cloud. The two output variables
"_occlusion" and "_Cs" are provided so that secondary images ie. render passes,
can be generated. The names "_occlusion" and "_Cs" have been chosen because rib
files produced by mtor/maya have default display channels with these names.
The scene must be rendered twice. A pre-pass render generates a point cloud file
that is subsequently converted to a brickmap in preparation for the second render -
the beauty pass. The point cloud or the
brickmap can be viewed using ptviewer or brickviewer. Again, Cutter is setup to
automatically use these utilities. Select the name of the map you wish
to view. A right mouse click or control click (OSX) will popup the menu shown
in figure 2.
Figure 2
